Datoteka:Interferenz.jpg
Prijeđi na navigaciju
Prijeđi na pretraživanje
Veličina ovog prikaza: 600 × 600 piksela. Ostale razlučivosti: 240 × 240 piksela | 480 × 480 piksela | 768 × 768 piksela | 1024 × 1024 piksela | 2000 × 2000 piksela.
Vidi sliku u punoj veličini (2000 × 2000 piksela, veličina datoteke: 634 KB, MIME tip: image/jpeg)
Sažetak
| Opis |
Deutsch: Simuliertes Interferenzbild zweier punktförmiger Quellen mit gleicher Wellenlänge. Die Lagen der Quellen sind durch Kreuze gekennzeichnet, die Maxima beider Wellen durch farbige Kreise. |
| Datum | |
| Izvor | Vlastito djelo postavljača |
| Autor | Dr. Schorsch 12:32, 19 Apr 2005 (UTC) (Dr. Schorsch (talk)) |
Licencija
Ja, nositelj autorskog prava za ovo djelo, ovime ga objavljujem pod sljedećim licencijama:
|
Dozvoljava se umnožavanje, dijeljenje i/ili mijenjanje ovog dokumenta pod uvjetima GNU-ove licence za slobodnu dokumentaciju, inačica 1.2 ili kasnija ako ju je objavio Free Software Foundation; bez nepromjenjivih ili obveznih dijelova i bez teksta na naslovnoj i/ili posljednjoj stranici. Kopija licencije je uključena u odjeljak naslovljen GNU-ove licence za slobodnu dokumentaciju. |
Ova datoteka je licencirana pod uvjetima Creative Commons Imenovanje-Dijeli pod istim uvjetima 3.0 nelokalizirane, 2.5 opće, 2.0 opće i 1.0 opće licencije.
- Slobodno smijete:
- dijeliti – umnožavati, distribuirati i javnosti priopćavati djelo
- remiksirati – prerađivati djelo
- Pod sljedećim uvjetima:
- imenovanje autora – Morate pripisati odgovarajuće autorske zasluge, dati poveznicu na licenciju, te naznačiti jesu li načinjene promjene autorskog djela. Prethodno navedeno možete učiniti na svaki razuman način, ali ne na način koji bi sugerirao da Vi ili Vaše korištenje licencorova djela ima izravno licencorovo odobrenje.
- dijeli pod istim uvjetima – Ako ovo djelo izmijenite, preoblikujete ili stvarate na osnovu tog materijala, svoje doprinose morate distribuirati pod istom ili kompatibilnom licencijom kao što je i licencija originala.
Možete odabrati licenciju prema vašem izboru.
Source Code
This is the source code of the program I used to create this image. Click on “Show source code” to display it.
The following program is under the GNU General Public License (GPL).
|
Ovo djelo je slobodan softver; možete ga redistribuirati i / ili mijenjati pod uvjetima GNU Opće javne licencije kako ju je objavila Free Software Foundation; inačica 2 licencije, ili bilo koje kasnije verzije. Ovaj rad se distribuira u nadi da će biti koristan, no bez ikakvih jamstava, te ne sadrži garanciju prodaje ili prikladnosti za određenu svrhu. Pogledajte inačicu 2 i inačicu 3 GNU Opće javne licencije za više detalja. |
; Program Written in IDL (Interactive Data Language)
; Free Interpreter availible at www.rsinc.com
; Written by Georg Wiora
; This Program is under the GNU General Public License (GPL)
;
; Create a display of interference patterns
; Save this text as file "Interference2.pro" to run it.
; Draw a circle
PRO circle,x,y,r,_REF_EXTRA=ex
n=ULONG(!DPI*r) > 1
phi = FINDGEN(n)/FLOAT(n)*2*!DPI
x1 = r*COS(phi)+x
y1 = r*SIN(phi)+y
PLOTS,[x1,x1[0]],[y1,y1[0]],_STRICT_EXTRA=ex
END
; Compute the interference
PRO Interference2
; Final Image Size
siz=2000
; No display if larger than 800x1600 pixel
pixmap=SIZ GT 800
; Wavelength in Pixel
lambda=160
; Half distance of the sources
dhalb = lambda
; Compute the distance of each point in an array from the
; center point: This is the phase of the signal
d1 = SHIFT(DIST(siz*2,siz),siz,siz/2)
; Sinus of distace with 0 LE amplitude LE 2
f = SIN(d1/lambda*2*!DPI)+1
; Compute Interference
inter = SHIFT(f,-dhalb,0)+SHIFT(f,dhalb,0)
; Get maximum and minimum
ma = MAX(inter,MIN=mi)
; Two colors are reserved for marking, the rest is gray scale
; Scale interference to byte range [0..253]
inter = BYTE((TEMPORARY(inter)-mi)/(ma-mi)*253)
; Use lookup table to display
DEVICE,DECOMPOSED=0
; Gray scale
LOADCT,0
; Half length of center cross bars in pixel
cs=30
; Half width of center cross bars in pixel
cb=3
; Set mark for center
; Horizontal left
inter[siz-dhalb-cs:siz-dhalb+cs, siz/2-cb:siz/2+cb] = 254
; Vertical left
inter[siz-dhalb-cb:siz-dhalb+cb, siz/2-cs:siz/2+cs] = 254
; Horizontal right
inter[siz+dhalb-cs:siz+dhalb+cs, siz/2-cb:siz/2+cb] = 255
; Vertical right
inter[siz+dhalb-cb:siz+dhalb+cb, siz/2-cs:siz/2+cs] = 255
; Open a visible or invisible window (depends on pixmap flag)
WINDOW,XSIZE=2*siz,YSIZE=siz,PIXMAP=pixmap
; Display the interference (only gray scale!)
TV,inter
; Draw circles on maximum locations
FOR i=0,2.5*siz/lambda DO $
BEGIN
; Maximum location left
circle,siz-dhalb,siz/2,(i+0.25)*lambda,THICK=6,/DEVICE,COLOR=254
; Maximum location right
circle,siz+dhalb,siz/2,(i+0.25)*lambda,THICK=6,/DEVICE,COLOR=255
ENDFOR
; Colortable 0-253 as gray scake
r = FINDGEN(256)/253*255
g=r
b=r
; 254 is green
r[254]=0
b[254]=0
g[254]=255
; 255 is red
r[255]=255
b[255]=0
g[255]=0
; Read image from display
im=TVRD()
; Crop invalid borders
im = im[siz/2:3*siz/2-1,*]
; Save as PNG with colortable
WRITE_PNG,'Interference2.png',im,r,g,b
; Convert to truecolor and write JPEG
imt = [[[r[im]]],[[g[im]]],[[b[im]]]]
; smooth image a little bit (saves bandwith in jpeg and is OK
; with high resolution)
imt[*,*,0] = SMOOTH(imt[*,*,0],3,/EDGE_TRUNCATE)
imt[*,*,1] = SMOOTH(imt[*,*,1],3,/EDGE_TRUNCATE)
imt[*,*,2] = SMOOTH(imt[*,*,2],3,/EDGE_TRUNCATE)
; Write as jpeg
WRITE_JPEG,'Interference2.jpg',TEMPORARY(imt),/PROGRESSIVE,$
QUALITY=90, TRUE=3
END
Povijest datoteke
Kliknite na datum/vrijeme kako biste vidjeli datoteku kakva je tada bila.
| Datum/Vrijeme | Minijatura | Dimenzije | Suradnik | Komentar | |
|---|---|---|---|---|---|
| sadašnja | 15:26, 19. travnja 2005. | | 2000 × 2000 (634 KB) | wikimediacommons>Xorx |
Uporaba datoteke
10 sljedećih stranica rabi ovu datoteku:
